Lunar Calculator

*Syntax Specification*

**Comments**

Terminals are indicated in bold font, and non-terminals are delimited by angle brackets “< >”. Operators are underlined.

**Infix Notation Syntax**

*Note: Whitespace is ignored within an infix notation expression.*

<command> ::= <assignment\_statement>

| <expression>

<assignment\_statement> ::= <identifier> = <expression>

<identifier> ::= **[a-zA-Z][a-zA-Z0-9\_]\***

<expression> ::= <expression> + <term>

| <expression> - <term>

| <term>

<term> ::= <term> \* <power>

| <term> / <power>

| <power>

<power> ::= <base> ^ <exponent>

| <factor>

<base> ::= <factor>

<exponent> ::= <factor> ^ <exponent>

| <factor>

<factor> ::= ( <expression> )

| <identifier>

| -<identifier>

| <number>

<number> ::= **[-]?[1-9][0-9,]\*[\.[0-9,]\*]?**

**Prefix Notation Syntax**

*Note: Whitespace will not be ignored within a prefix notation expression.*

<command> ::= <assignment\_statement>

| <expression>

<assignment\_statement> ::= <identifier> = <expression>

<identifier> ::= **[a-zA-Z][a-zA-Z0-9\_]\***

<expression> ::= + <expression> <expression>

| - <expression> <expression>

| \* <expression> <expression>

| / <expression> <expression>

| ^ <expression> <expression>

| <operand>

<operand> ::= <identifier>

| -<identifier>

| <number>

<number> ::= **[-]?[1-9][0-9,]\*[\.[0-9,]\*]?**

**Postfix Notation Syntax**

*Note: Whitespace will not be ignored within a postfix notation expression.*

<command> ::= <assignment\_statement>

| <expression>

<assignment\_statement> ::= <identifier> = <expression>

<identifier> ::= **[a-zA-Z][a-zA-Z0-9\_]\***

<expression> ::= <expression> <expression> +

| <expression> <expression> -

| <expression> <expression> \*

| <expression> <expression> /

| <expression> <expression> ^

| <operand>

<operand> ::= <identifier>

| -<identifier>

| <number>

<number> ::= **[-]?[1-9][0-9,]\*[\.[0-9,]\*]?**